threeeye
bc1d038eac
Squashed backup commit (no shallow-clone history issues) of xiaomi-mt6833-dev/kernel_xiaomi_mt6833 (lineage-23.2 branch, upstream commit 9eece662e) plus all fixes applied to get everpal_defconfig building clean against a modern (GCC 15.2.0) toolchain -- see the previous commit message on the lineage-23.2 branch (also in this repo history is not available here since this is a squashed snapshot; full incremental history lives in the local DL380 checkout and the upstream GitHub remote). Upstream: https://github.com/xiaomi-mt6833-dev/kernel_xiaomi_mt6833 (lineage-23.2)
82 lines
1.3 KiB
Plaintext
82 lines
1.3 KiB
Plaintext
// SPDX-License-Identifier: GPL-2.0
|
|
/// Make sure calls to d_find_alias() have a corresponding call to dput().
|
|
//
|
|
// Keywords: d_find_alias, dput
|
|
//
|
|
// Confidence: Moderate
|
|
// URL: http://coccinelle.lip6.fr/
|
|
// Options: --include-headers
|
|
|
|
virtual context
|
|
virtual org
|
|
virtual patch
|
|
virtual report
|
|
|
|
@r exists@
|
|
local idexpression struct dentry *dent;
|
|
expression E, E1;
|
|
statement S1, S2;
|
|
position p1, p2;
|
|
@@
|
|
(
|
|
if (!(dent@p1 = d_find_alias(...))) S1
|
|
|
|
|
dent@p1 = d_find_alias(...)
|
|
)
|
|
|
|
<...when != dput(dent)
|
|
when != if (...) { <+... dput(dent) ...+> }
|
|
when != true !dent || ...
|
|
when != dent = E
|
|
when != E = dent
|
|
if (!dent || ...) S2
|
|
...>
|
|
(
|
|
return <+...dent...+>;
|
|
|
|
|
return @p2 ...;
|
|
|
|
|
dent@p2 = E1;
|
|
|
|
|
E1 = dent;
|
|
)
|
|
|
|
@depends on context@
|
|
local idexpression struct dentry *r.dent;
|
|
position r.p1,r.p2;
|
|
@@
|
|
* dent@p1 = ...
|
|
...
|
|
(
|
|
* return@p2 ...;
|
|
|
|
|
* dent@p2
|
|
)
|
|
|
|
|
|
@script:python depends on org@
|
|
p1 << r.p1;
|
|
p2 << r.p2;
|
|
@@
|
|
cocci.print_main("Missing call to dput()",p1)
|
|
cocci.print_secs("",p2)
|
|
|
|
@depends on patch@
|
|
local idexpression struct dentry *r.dent;
|
|
position r.p2;
|
|
@@
|
|
(
|
|
+ dput(dent);
|
|
return @p2 ...;
|
|
|
|
|
+ dput(dent);
|
|
dent@p2 = ...;
|
|
)
|
|
|
|
@script:python depends on report@
|
|
p1 << r.p1;
|
|
p2 << r.p2;
|
|
@@
|
|
msg = "Missing call to dput() at line %s."
|
|
coccilib.report.print_report(p1[0], msg % (p2[0].line))
|